#@TYPE: Machine
#@NAME: Starter Board for ConnectCore for i.MX6UL
#@DESCRIPTION: Machine configuration for Digi's ConnectCore 6UL Starter Board.

# Include the machine configuration for Digi's ConnectCore 6UL.
include conf/machine/include/ccimx6ul.inc

# U-Boot configurations
# Last one is the default (the one the symlinks point at)
UBOOT_CONFIG ??= "ccimx6ulstarter1GB ccimx6ulstarter512MB ccimx6ulstarter"
UBOOT_CONFIG[ccimx6ulstarter1GB] = "ccimx6ulstarter1GB_defconfig,,u-boot-dtb.${UBOOT_SUFFIX}"
UBOOT_CONFIG[ccimx6ulstarter512MB] = "ccimx6ulstarter512MB_defconfig,,u-boot-dtb.${UBOOT_SUFFIX}"
UBOOT_CONFIG[ccimx6ulstarter] = "ccimx6ulstarter_defconfig,,u-boot-dtb.${UBOOT_SUFFIX}"

KERNEL_DEVICETREE ?= " \
    imx6ul-ccimx6ulstarter.dtb \
    imx6ul-ccimx6ulstarter-wb.dtb \
    imx6ul-ccimx6ulstarter-id129.dtb \
"
KERNEL_DEVICETREE:use-mainline-bsp ?= "imx6ul-ccimx6ulsbcexpress.dtb"

KERNEL_DEFCONFIG ?= "arch/arm/configs/ccimx6ul_defconfig"

SERIAL_CONSOLES ?= "115200;ttymxc4"

# Bluetooth tty
BT_TTY ?= "ttymxc0"

# Image FS types
IMAGE_FSTYPES ?= '${@bb.utils.contains("IMAGE_FEATURES", "read-only-rootfs", \
				       "tar.bz2 boot.ubifs recovery.ubifs squashfs", \
				       "tar.bz2 ubifs boot.ubifs recovery.ubifs", d)}'

# Default image for install scripts
DEFAULT_IMAGE_NAME ?= "core-image-base"

# Boot artifacts to be copied from the deploy dir to the installer ZIP
BOOTABLE_ARTIFACTS = " \
    u-boot-ccimx6ulstarter1GB.imx \
    u-boot-ccimx6ulstarter512MB.imx \
    u-boot-ccimx6ulstarter.imx \
"
