From 3f8c5bea0650dd78f41f9f3553b5945ad3758c35 Mon Sep 17 00:00:00 2001
From: Javier Viguera <javier.viguera@digi.com>
Date: Mon, 4 Sep 2017 12:24:09 +0200
Subject: [PATCH] libsoc: add generic recipe to build from GIT

Also configure DEY to build the GIT version of libsoc.

https://jira.digi.com/browse/DEL-4816

Signed-off-by: Javier Viguera <javier.viguera@digi.com>
---
 meta-digi-dey/conf/distro/dey.conf            |  3 ++
 .../recipes-support/libsoc/libsoc_git.bb      | 38 +++++++++++++++++++
 2 files changed, 41 insertions(+)
 create mode 100644 meta-digi-dey/recipes-support/libsoc/libsoc_git.bb

diff --git a/meta-digi-dey/conf/distro/dey.conf b/meta-digi-dey/conf/distro/dey.conf
index 39b6132d7..3bedfb74b 100644
--- a/meta-digi-dey/conf/distro/dey.conf
+++ b/meta-digi-dey/conf/distro/dey.conf
@@ -57,6 +57,9 @@ PREFERRED_VERSION_linux-yocto_qemumips ?= "4.8%"
 PREFERRED_VERSION_linux-yocto_qemumips64 ?= "4.8%"
 PREFERRED_VERSION_linux-yocto_qemuppc ?= "4.8%"
 
+# Use git recipe for libsoc
+PREFERRED_VERSION_libsoc = "git"
+
 SDK_NAME = "${DISTRO}-${TCLIBC}-${SDK_ARCH}-${IMAGE_BASENAME}-${TUNE_PKGARCH}"
 SDKPATH = "/opt/${DISTRO}/${SDK_VERSION}"
 
diff --git a/meta-digi-dey/recipes-support/libsoc/libsoc_git.bb b/meta-digi-dey/recipes-support/libsoc/libsoc_git.bb
new file mode 100644
index 000000000..e3c4da70d
--- /dev/null
+++ b/meta-digi-dey/recipes-support/libsoc/libsoc_git.bb
@@ -0,0 +1,38 @@
+# Copyright (C) 2017 Digi International Inc.
+
+SUMMARY = "Library for interfacing with common SoC peripherals"
+DESCRIPTION = "libsoc is a C library to interface with common peripherals (gpio, i2c, spi, pwm) \
+               found in SoC (System on Chips) through generic Linux Kernel interfaces."
+
+HOMEPAGE = "https://github.com/jackmitch/libsoc"
+
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=e0bfebea12a718922225ba987b2126a5"
+
+inherit autotools pkgconfig python-dir
+
+SRCBRANCH ?= "master"
+SRCREV = "${AUTOREV}"
+SRC_URI = "git://github.com/jackmitch/libsoc.git"
+
+S = "${WORKDIR}/git"
+
+BOARD ??= "devboard"
+
+PACKAGECONFIG ?= ""
+
+PACKAGECONFIG[disabledebug] = "--disable-debug,,"
+PACKAGECONFIG[allboardconfigs] = "--with-board-configs,,"
+PACKAGECONFIG[enableboardconfig] = "--enable-board=${BOARD},,"
+PACKAGECONFIG[python] = "--enable-python=${PYTHON_PN},,${PYTHON_PN}"
+
+PACKAGES =+ "${@bb.utils.contains('PACKAGECONFIG', 'python', \
+    '${PYTHON_PN}-libsoc-staticdev ${PYTHON_PN}-libsoc', '', d)}"
+
+RDEPENDS_${PN} = "libgcc"
+RDEPENDS_${PYTHON_PN}-libsoc = "${PN} ${PYTHON_PN}-ctypes"
+
+FILES_${PYTHON_PN}-libsoc-staticdev += "${PYTHON_SITEPACKAGES_DIR}/*/*.a"
+FILES_${PYTHON_PN}-libsoc += "${PYTHON_SITEPACKAGES_DIR}"
+
+DEFAULT_PREFERENCE = "-1"