From 47bcb5e3ca4ddddc560e30539767b9cfcaf8f841 Mon Sep 17 00:00:00 2001
From: Alex Gonzalez <alex.gonzalez@digi.com>
Date: Fri, 16 Nov 2012 16:12:32 +0100
Subject: [PATCH] base-password: Override whole recipe in meta-digi.

The original recipe is based in meta/recipes-core. We want to add a shadow
file for the del-image-minimal target.

The best way would be to add a bbappend overlay, however the original
recipe prepends the populate_packages function with a:

preinst = blahblah

This makes it impossible for a bbappended recipe to add anything to the
preinst script, which is needed to install the shadow file.

Hence the only solution is to duplicated the recipe and increase PR.

Signed-off-by: Alex Gonzalez <alex.gonzalez@digi.com>
---
 .../base-passwd-3.5.24/add-shadow-file.patch  |  38 +++++++
 .../base-passwd-3.5.24/base-passwd_3.5.24.bb  | 106 ++++++++++++++++++
 .../base-passwd-3.5.24/nobash.patch           |  23 ++++
 .../base-passwd-3.5.24/root-home.patch        |  16 +++
 4 files changed, 183 insertions(+)
 create mode 100644 meta-digi-arm/recipes-core/base-passwd-3.5.24/add-shadow-file.patch
 create mode 100644 meta-digi-arm/recipes-core/base-passwd-3.5.24/base-passwd_3.5.24.bb
 create mode 100644 meta-digi-arm/recipes-core/base-passwd-3.5.24/nobash.patch
 create mode 100644 meta-digi-arm/recipes-core/base-passwd-3.5.24/root-home.patch

diff --git a/meta-digi-arm/recipes-core/base-passwd-3.5.24/add-shadow-file.patch b/meta-digi-arm/recipes-core/base-passwd-3.5.24/add-shadow-file.patch
new file mode 100644
index 000000000..9d3754117
--- /dev/null
+++ b/meta-digi-arm/recipes-core/base-passwd-3.5.24/add-shadow-file.patch
@@ -0,0 +1,38 @@
+From ac7746a741e005df07f35cf19bcf25ffff517750 Mon Sep 17 00:00:00 2001
+From: Alex Gonzalez <alex.gonzalez@digi.com>
+Date: Fri, 16 Nov 2012 12:05:15 +0100
+Subject: [PATCH] shadow.master: Adding shadow file.
+
+The root password is "root" when debug-tweaks is not enabled. Otherwise
+the password is empty.
+
+Signed-off-by: Alex Gonzalez <alex.gonzalez@digi.com>
+---
+ shadow.master |   18 ++++++++++++++++++
+ 1 file changed, 18 insertions(+)
+ create mode 100644 shadow.master
+
+diff --git a/shadow.master b/shadow.master
+new file mode 100644
+index 0000000..856efb0
+--- /dev/null
++++ b/shadow.master
+@@ -0,0 +1,18 @@
++root:\$1\$o/c1Q/E4\$jLGsldHxRdlYpEI3v6Sdv1::0:::::
++daemon:*::0:::::
++bin:*::0:::::
++sys:*::0:::::
++sync:*::0:::::
++games:*::0:::::
++man:*::0:::::
++lp:*::0:::::
++mail:*::0:::::
++news:*::0:::::
++uucp:*::0:::::
++proxy:*::0:::::
++www-data:*::0:::::
++backup:*::0:::::
++list:*::0:::::
++irc:*::0:::::
++gnats:*::0:::::
++nobody:*::0:::::
diff --git a/meta-digi-arm/recipes-core/base-passwd-3.5.24/base-passwd_3.5.24.bb b/meta-digi-arm/recipes-core/base-passwd-3.5.24/base-passwd_3.5.24.bb
new file mode 100644
index 000000000..ffcdd91e6
--- /dev/null
+++ b/meta-digi-arm/recipes-core/base-passwd-3.5.24/base-passwd_3.5.24.bb
@@ -0,0 +1,106 @@
+SUMMARY = "Base system master password/group files."
+DESCRIPTION = "The master copies of the user database files (/etc/passwd and /etc/group).  The update-passwd tool is also provided to keep the system databases synchronized with these master files."
+SECTION = "base"
+PR = "r1"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=eb723b61539feef013de476e68b5c50a"
+
+SRC_URI = "${DEBIAN_MIRROR}/main/b/base-passwd/base-passwd_${PV}.tar.gz \
+           file://nobash.patch \
+           file://root-home.patch \
+           file://add-shadow-file.patch"
+
+SRC_URI[md5sum] = "8f6b9420c50e90edaff41eb2fb7e9e16"
+SRC_URI[sha256sum] = "196083d6f675190d4e2cede0a5fa6b3c91088705c5386f76292fec8e74b6369e"
+
+S = "${WORKDIR}/base-passwd"
+
+inherit autotools
+
+SSTATEPOSTINSTFUNCS += "base_passwd_sstate_postinst"
+
+do_install () {
+	install -d -m 755 ${D}${sbindir}
+	install -o root -g root -p -m 755 update-passwd ${D}${sbindir}/
+	install -d -m 755 ${D}${mandir}/man8 ${D}${mandir}/pl/man8
+	install -p -m 644 man/update-passwd.8 ${D}${mandir}/man8/
+	install -p -m 644 man/update-passwd.pl.8 \
+		${D}${mandir}/pl/man8/update-passwd.8
+	gzip -9 ${D}${mandir}/man8/* ${D}${mandir}/pl/man8/*
+	install -d -m 755 ${D}${datadir}/base-passwd
+	install -o root -g root -p -m 644 passwd.master ${D}${datadir}/base-passwd/
+	install -o root -g root -p -m 644 group.master ${D}${datadir}/base-passwd/
+	install -o root -g shadow -p -m 644 shadow.master ${D}${datadir}/base-passwd/
+
+	install -d -m 755 ${D}${docdir}/${BPN}
+	install -p -m 644 debian/changelog ${D}${docdir}/${BPN}/
+	gzip -9 ${D}${docdir}/${BPN}/*
+	install -p -m 644 README ${D}${docdir}/${BPN}/
+	install -p -m 644 debian/copyright ${D}${docdir}/${BPN}/
+}
+
+base_passwd_sstate_postinst() {
+	if [ "${BB_CURRENTTASK}" = "populate_sysroot" -o "${BB_CURRENTTASK}" = "populate_sysroot_setscene" ]
+	then
+		# Staging does not copy ${sysconfdir} files into the
+		# target sysroot, so we need to do so manually. We
+		# put these files in the target sysroot so they can
+		# be used by recipes which use custom user/group
+		# permissions.
+		install -d -m 755 ${STAGING_DIR_TARGET}${sysconfdir}
+		install -p -m 644 ${STAGING_DIR_TARGET}${datadir}/base-passwd/passwd.master ${STAGING_DIR_TARGET}${sysconfdir}/passwd
+		install -p -m 644 ${STAGING_DIR_TARGET}${datadir}/base-passwd/group.master ${STAGING_DIR_TARGET}${sysconfdir}/group
+		install -p -m 644 ${STAGING_DIR_TARGET}${datadir}/base-passwd/shadow.master ${STAGING_DIR_TARGET}${sysconfdir}/shadow
+	fi
+}
+
+python populate_packages_prepend() {
+	# Add in the preinst function for ${PN}
+	# We have to do this here as prior to this, passwd/group.master
+	# would be unavailable. We need to create these files at preinst
+	# time before the files from the package may be available, hence
+	# storing the data from the files in the preinst directly.
+
+	f = open(d.expand("${STAGING_DATADIR}/base-passwd/passwd.master"), 'r')
+	passwd = "".join(f.readlines())
+	f.close()
+	f = open(d.expand("${STAGING_DATADIR}/base-passwd/group.master"), 'r')
+	group = "".join(f.readlines())
+	f.close()
+	f = open(d.expand("${STAGING_DATADIR}/base-passwd/shadow.master"), 'r')
+	shadow = "".join(f.readlines())
+	f.close()
+
+	preinst = """#!/bin/sh
+if [ ! -e $D${sysconfdir}/passwd ]; then
+	cat << EOF > $D${sysconfdir}/passwd
+""" + passwd + """EOF
+fi
+if [ ! -e $D${sysconfdir}/group ]; then
+	cat << EOF > $D${sysconfdir}/group
+""" + group + """EOF
+fi
+if [ ! -e $D${sysconfdir}/shadow ]; then
+	cat << EOF > $D${sysconfdir}/shadow
+""" + shadow + """EOF
+fi
+chmod 640 $D${sysconfdir}/shadow
+chgrp shadow $D${sysconfdir}/shadow
+"""
+	d.setVar('pkg_preinst_${PN}', preinst)
+}
+
+addtask do_package after do_populate_sysroot
+
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGES =+ "${PN}-update"
+FILES_${PN}-update = "${sbindir}/* ${datadir}/${PN}"
+
+pkg_postinst_${PN}-update () {
+#!/bin/sh
+if [ -n "$D" ]; then
+	exit 0
+fi
+${sbindir}/update-passwd
+}
diff --git a/meta-digi-arm/recipes-core/base-passwd-3.5.24/nobash.patch b/meta-digi-arm/recipes-core/base-passwd-3.5.24/nobash.patch
new file mode 100644
index 000000000..637157644
--- /dev/null
+++ b/meta-digi-arm/recipes-core/base-passwd-3.5.24/nobash.patch
@@ -0,0 +1,23 @@
+use /bin/sh instead of /bin/bash, since the latter may not be included in
+some images such as minimal
+
+comment added by Kevin Tian <kevin.tian@intel.com>, 2010-07-06
+
+remove "*" for root since we don't have a /etc/shadow so far.
+
+by Kevin Tian <kevin.tian@intel.com>, 2010-07-06
+
+Patch managed by http://www.mn-logistik.de/unsupported/pxa250/patcher
+
+Upstream-Status: Invalid [configuration]
+
+Signed-off-by: Scott Garman <scott.a.garman@intel.com>
+
+--- base-passwd/passwd.master~nobash
++++ base-passwd/passwd.master
+@@ -1,4 +1,4 @@
+-root:*:0:0:root:/root:/bin/bash
++root::0:0:root:/root:/bin/sh
+ daemon:*:1:1:daemon:/usr/sbin:/bin/sh
+ bin:*:2:2:bin:/bin:/bin/sh
+ sys:*:3:3:sys:/dev:/bin/sh
diff --git a/meta-digi-arm/recipes-core/base-passwd-3.5.24/root-home.patch b/meta-digi-arm/recipes-core/base-passwd-3.5.24/root-home.patch
new file mode 100644
index 000000000..eab77f124
--- /dev/null
+++ b/meta-digi-arm/recipes-core/base-passwd-3.5.24/root-home.patch
@@ -0,0 +1,16 @@
+we use /home/root instead of /root
+
+Comment added by Kevin Tian <kevin.tian@intel.com>, 2010-07-06
+
+Upstream-Status: Inappropriate [configuration]
+
+Signed-off-by: Scott Garman <scott.a.garman@intel.com>
+
+--- base-passwd/passwd.master.orig	2005-07-08 06:26:22.000000000 +0200
++++ base-passwd/passwd.master	2005-07-08 06:31:58.000000000 +0200
+@@ -1,4 +1,4 @@
+-root::0:0:root:/root:/bin/sh
++root::0:0:root:/home/root:/bin/sh
+ daemon:*:1:1:daemon:/usr/sbin:/bin/sh
+ bin:*:2:2:bin:/bin:/bin/sh
+ sys:*:3:3:sys:/dev:/bin/sh