From 77be1508719129d52b30a8bb5e4a6f8a81ea3dc3 Mon Sep 17 00:00:00 2001
From: Javier Viguera <javier.viguera@digi.com>
Date: Thu, 27 Feb 2014 13:32:41 +0100
Subject: [PATCH] meta-digi-arm: add new package u-boot-dey-fw-utils

Provides fw_printenv/fw_setenv utilities to read/write the u-boot
environment from Linux.

https://jira.digi.com/browse/DEL-800

Signed-off-by: Javier Viguera <javier.viguera@digi.com>
---
 meta-digi-arm/conf/machine/include/ccimx6.inc |  7 ++++-
 .../ccimx6adpt/fw_env.config                  |  7 +++++
 .../u-boot/u-boot-dey-fw-utils_2013.04.bb     | 30 +++++++++++++++++++
 3 files changed, 43 insertions(+), 1 deletion(-)
 create mode 100644 meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils-2013.04/ccimx6adpt/fw_env.config
 create mode 100644 meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils_2013.04.bb

diff --git a/meta-digi-arm/conf/machine/include/ccimx6.inc b/meta-digi-arm/conf/machine/include/ccimx6.inc
index 56540c894..31e1259d9 100644
--- a/meta-digi-arm/conf/machine/include/ccimx6.inc
+++ b/meta-digi-arm/conf/machine/include/ccimx6.inc
@@ -16,7 +16,12 @@ MACHINE_FIRMWARE ?= ""
 MACHINE_FIRMWARE_append = " firmware-imx-vpu-imx6q"
 MACHINE_FIRMWARE_append = " ${@base_conditional('HAVE_BT', '1' , 'firmware-atheros-ar3k', '', d)}"
 
-MACHINE_EXTRA_RDEPENDS    += "e2fsprogs e2fsprogs-mke2fs parted"
+MACHINE_EXTRA_RDEPENDS += " \
+    e2fsprogs \
+    e2fsprogs-mke2fs \
+    parted \
+    u-boot-dey-fw-utils \
+"
 MACHINE_EXTRA_RRECOMMENDS += "${MACHINE_FIRMWARE}"
 MACHINE_EXTRA_RRECOMMENDS += "fsl-alsa-plugins"
 
diff --git a/meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils-2013.04/ccimx6adpt/fw_env.config b/meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils-2013.04/ccimx6adpt/fw_env.config
new file mode 100644
index 000000000..040cd8e30
--- /dev/null
+++ b/meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils-2013.04/ccimx6adpt/fw_env.config
@@ -0,0 +1,7 @@
+# Configuration file for fw_(printenv/setenv) utility.
+# Up to two entries are valid, in this case the redundant
+# environment sector is assumed present.
+
+# Device name        Offset	 Size
+/dev/mmcblk0boot1    0x1C0000    0x4000
+/dev/mmcblk0boot1    0x1E0000    0x4000
diff --git a/meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils_2013.04.bb b/meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils_2013.04.bb
new file mode 100644
index 000000000..20ad8402d
--- /dev/null
+++ b/meta-digi-arm/recipes-bsp/u-boot/u-boot-dey-fw-utils_2013.04.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "U-boot bootloader fw_printenv/setenv utils"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=1707d6db1d42237583f50183a5651ecb"
+SECTION = "bootloader"
+
+include u-boot-dey-rev_${PV}.inc
+
+SRC_URI += "file://fw_env.config"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'HOSTCC="${CC}" HOSTSTRIP="true"'
+
+inherit uboot-config
+
+do_compile() {
+	oe_runmake ${UBOOT_MACHINE}
+	oe_runmake env
+}
+
+do_install() {
+	install -d ${D}${base_sbindir} ${D}${sysconfdir}
+	install -m 0755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+	ln -sf fw_printenv ${D}${base_sbindir}/fw_setenv
+	install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+COMPATIBLE_MACHINE = "(mx6)"