diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8.16.inc b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8.16.inc
deleted file mode 100644
index fe0475119..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8.16.inc
+++ /dev/null
@@ -1,17 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017-2021 NXP
-# Copyright (C) 2018 O.S. Systems Software LTDA.
-SECTION = "base"
-LICENSE = "Proprietary"
-LIC_FILES_CHKSUM = "file://COPYING;md5=d3c315c6eaa43e07d8c130dc3a04a011"
-
-SRC_URI = " \
-    ${FSL_MIRROR}/firmware-imx-${PV}.bin;fsl-eula=true \
-"
-
-SRC_URI[md5sum] = "9ed2923c0eb511c7fcf37dd607944124"
-SRC_URI[sha256sum] = "65f829a9e2597bffc58a680aaefa638122144a083633d1ae09b3aec1d9f8ab84"
-
-S = "${WORKDIR}/firmware-imx-${PV}"
-
-inherit fsl-eula-unpack
diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8_8.16.bb b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8_8.16.bb
deleted file mode 100644
index 9d96d5c6b..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8_8.16.bb
+++ /dev/null
@@ -1,23 +0,0 @@
-# Copyright 2018-2021 NXP
-SUMMARY = "Freescale i.MX firmware for 8 family"
-DESCRIPTION = "Freescale i.MX firmware for 8 family"
-
-require firmware-imx-${PV}.inc
-
-inherit deploy
-
-do_install[noexec] = "1"
-
-do_deploy() {
-    # Cadence HDMI
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${DEPLOYDIR}
-}
-addtask deploy after do_install before do_build
-
-PACKAGE_ARCH = "${MACHINE_SOCARCH}"
-
-COMPATIBLE_MACHINE      = "(mx8-nxp-bsp)"
-COMPATIBLE_MACHINE:mx8m-nxp-bsp = "(^$)"
-COMPATIBLE_MACHINE:mx8x-nxp-bsp = "(^$)"
diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8m_8.16.bb b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8m_8.16.bb
deleted file mode 100644
index 0f71f067e..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8m_8.16.bb
+++ /dev/null
@@ -1,24 +0,0 @@
-# Copyright 2018-2021 NXP
-SUMMARY = "Freescale i.MX firmware for 8M and 8M Mini family"
-DESCRIPTION = "Freescale i.MX firmware for 8M and 8M Mini family"
-
-require firmware-imx-${PV}.inc
-
-inherit deploy
-
-do_install[noexec] = "1"
-
-do_deploy() {
-    # Synopsys DDR
-    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
-        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
-    done
-    # Cadence DP and HDMI
-    install -m 0644 ${S}/firmware/hdmi/cadence/signed_dp_imx8m.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/signed_hdmi_imx8m.bin ${DEPLOYDIR}
-}
-addtask deploy after do_install before do_build
-
-PACKAGE_ARCH = "${MACHINE_SOCARCH}"
-
-COMPATIBLE_MACHINE = "(mx8m-nxp-bsp|imx-boot-container)"
diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.16.bb b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.16.bb
deleted file mode 100644
index 480e08c26..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.16.bb
+++ /dev/null
@@ -1,133 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017-2020 NXP
-# Copyright (C) 2018 O.S. Systems Software LTDA.
-SUMMARY = "Freescale i.MX firmware"
-DESCRIPTION = "Freescale i.MX firmware such as for the VPU"
-
-require firmware-imx-${PV}.inc
-
-PE = "1"
-
-inherit allarch
-
-do_install() {
-    install -d ${D}${nonarch_base_libdir}/firmware/imx
-
-    # SDMA Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/sdma
-    install -m 0644 ${S}/firmware/sdma/* ${D}${nonarch_base_libdir}/firmware/imx/sdma
-    # Comment these lines to use sdma-imx6q/7d.bin from here and not linux-firmware
-    #rm -f ${D}${nonarch_base_libdir}/firmware/imx/sdma/sdma-imx6q.bin
-    #rm -f ${D}${nonarch_base_libdir}/firmware/imx/sdma/sdma-imx7d.bin
-
-    # EASRC Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/easrc
-    install -m 0644 ${S}/firmware/easrc/* ${D}${nonarch_base_libdir}/firmware/imx/easrc/
-
-    # XCVR Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/xcvr
-    install -m 0644 ${S}/firmware/xcvr/* ${D}${nonarch_base_libdir}/firmware/imx/xcvr/
-
-    # XUVI Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/xuvi
-    install -m 0644 ${S}/firmware/xuvi/* ${D}${nonarch_base_libdir}/firmware/imx/xuvi/
-
-    # EPDC Firmware section
-    # NOTE:
-    # epdc_ED060XH2C1.fw file has .nonrestricted suffix in the source archive, hence it should
-    # be installed with a different name
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/epdc
-    install -m 0644 ${S}/firmware/epdc/*.fw ${D}${nonarch_base_libdir}/firmware/imx/epdc/
-    install -m 0644 ${S}/firmware/epdc/epdc_ED060XH2C1.fw.nonrestricted ${D}${nonarch_base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw
-
-    # HDMI Firmware section
-    # NOTE:
-    # Only install pre-defined list of firmware files, since the source archive contains
-    # also HDMI binary files for imx8m derivatives, which are taken care of by another recipe
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${D}${nonarch_base_libdir}/firmware
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${D}${nonarch_base_libdir}/firmware
-    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${D}${nonarch_base_libdir}/firmware
-
-    # VPU Firmware section
-    # NOTE:
-    # Do the same thing as above for HDMI - only install a pre-defined list of firmware files,
-    # as some of other files are provided by packages from other recipes.
-    install -d ${D}${nonarch_base_libdir}/firmware/vpu
-    install -m 0644 ${S}/firmware/vpu/vpu_fw_imx*.bin ${D}${nonarch_base_libdir}/firmware/vpu
-}
-
-#
-# This prepend is here to produce separate packages containing firmware,
-# which could be included separately based on the machine definition.
-#
-# It operates similar to the FILES mechanism by travesing through
-# ${D} + folder supplied as a first parameter, matches the regexp supplied
-# as second one, and for every file match - it creates a separate package,
-# which contains only files that matches the pattern.
-#
-python populate_packages:prepend() {
-    easrcdir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/easrc', d)
-    do_split_packages(d, easrcdir, '^easrc-([^_]*).*\.bin',
-                      output_pattern='firmware-imx-easrc-%s',
-                      description='Freescale IMX EASRC Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    vpudir = bb.data.expand('${nonarch_base_libdir}/firmware/vpu', d)
-    do_split_packages(d, vpudir, '^vpu_fw_([^_]*).*\.bin',
-                      output_pattern='firmware-imx-vpu-%s',
-                      description='Freescale IMX VPU Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    sdmadir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/sdma', d)
-    do_split_packages(d, sdmadir, '^sdma-([^-]*).*\.bin',
-                      output_pattern='firmware-imx-sdma-%s',
-                      description='Freescale IMX SDMA Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    xcvrdir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/xcvr', d)
-    do_split_packages(d, xcvrdir, '^xcvr-([^_]*).*\.bin',
-                      output_pattern='firmware-imx-xcvr-%s',
-                      description='Freescale IMX XCVR Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    xuvidir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/xuvi', d)
-    do_split_packages(d, xuvidir, '^vpu_fw_([^_]*).*\.bin',
-                      output_pattern='firmware-imx-xuvi-%s',
-                      description='Freescale IMX XUVI Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-}
-
-# Declare a contract that we would provide packages produced by prepend above
-PACKAGES_DYNAMIC = "${PN}-vpu-* ${PN}-sdma-* ${PN}-easrc-* ${PN}-xcvr-* ${PN}-xuvi-*"
-
-#
-# Deal with the rest of Firmware packages here
-#
-# Provide EPDC and HDMI Firmware in common packages as they tend to be special in
-# terms of the content.
-#
-# NOTE: PACKAGES are defined explicitly here in order to remove the auto-generated
-# complimentary packages (-dev and -dbg).
-# This is done in order to be able to keep the main package empty and fail when
-# somebody tries to install it in the image.
-# If -dev package is present in that setup, and dev-pkgs is enabled in
-# IMAGE_FEATURES - this leads to a failure during do_rootfs() while all -dev
-# packages would be installed, and -dev package would fail because the main one
-# is empty.
-# Therefore, we opt-out from producing -dev package here, since also for firmware
-# files it makes no sense.
-PACKAGES = "${PN} ${PN}-epdc ${PN}-hdmi"
-
-FILES:${PN}-epdc = "${nonarch_base_libdir}/firmware/imx/epdc/"
-FILES:${PN}-hdmi = " \
-    ${nonarch_base_libdir}/firmware/hdmitxfw.bin \
-    ${nonarch_base_libdir}/firmware/hdmirxfw.bin \
-    ${nonarch_base_libdir}/firmware/dpfw.bin \
-"
-
-COMPATIBLE_MACHINE = "(imx-nxp-bsp|use-mainline-bsp)"
diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.16.bbappend b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.16.bbappend
new file mode 100644
index 000000000..c4f7ee37c
--- /dev/null
+++ b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.16.bbappend
@@ -0,0 +1,8 @@
+# Copyright (C) 2022, Digi International Inc.
+
+do_install:append() {
+	# meta-freescale deletes the SDMA firmware provided by the firmware-imx package,
+	# in favor of the generic one provided by the linux-firmware package. The one
+	# provided by NXP is more up-to-date, so we want it back.
+	install -m 0644 ${S}/firmware/sdma/* ${D}${nonarch_base_libdir}/firmware/imx/sdma
+}