diff --git a/meta-digi-arm/conf/machine/include/imx-digi-base.inc b/meta-digi-arm/conf/machine/include/imx-digi-base.inc
index 44304219a..c4748e379 100644
--- a/meta-digi-arm/conf/machine/include/imx-digi-base.inc
+++ b/meta-digi-arm/conf/machine/include/imx-digi-base.inc
@@ -279,6 +279,7 @@ PREFERRED_VERSION_optee-test:mx8-nxp-bsp   ??= "3.19.0.imx"
 PREFERRED_VERSION_optee-test:mx9-nxp-bsp   ??= "3.19.0.imx"
 
 # Machine learning backports from NXP's lf-6.1.1_1.0.0 release
+PREFERRED_VERSION_deepview-rt:ccimx93 = "2.4.46.1-aarch64"
 PREFERRED_VERSION_tensorflow-lite:ccimx93 = "2.10.0"
 PREFERRED_VERSION_tensorflow-lite-host-tools:ccimx93 = "2.10.0"
 PREFERRED_VERSION_tensorflow-lite-host-tools-native:ccimx93 = "2.10.0"
diff --git a/meta-digi-dey/dynamic-layers/meta-ml/recipes-libraries/deepview-rt/deepview-rt_2.4.46.1-aarch64.bb b/meta-digi-dey/dynamic-layers/meta-ml/recipes-libraries/deepview-rt/deepview-rt_2.4.46.1-aarch64.bb
new file mode 100644
index 000000000..ec22eec23
--- /dev/null
+++ b/meta-digi-dey/dynamic-layers/meta-ml/recipes-libraries/deepview-rt/deepview-rt_2.4.46.1-aarch64.bb
@@ -0,0 +1,57 @@
+DESCRIPTION = "This package includes the updated and experimental ModelRunner for TensorFlow Lite and ARM NN. Also in this repository is a pre-release of DeepViewRT with support for the OpenVX backend."
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ea25d099982d035af85d193c88a1b479"
+
+DEPENDS = "python3 python3-pip-native"
+
+SRC_URI = "${FSL_MIRROR}/${BPN}-${PV}.bin;fsl-eula=true"
+SRC_URI[md5sum] = "a4782e44df2254d30f7c6b0a45c4102e"
+SRC_URI[sha256sum] = "40d6c12bbe5fc29a257a1717684ec650bd390eb1565c5bca82ec56e3ffbcf918"
+S = "${WORKDIR}/${BPN}-${PV}"
+
+inherit fsl-eula-unpack python3native
+
+PACKAGECONFIG ?= "${PACKAGECONFIG_OPENVX}"
+PACKAGECONFIG_OPENVX                    = ""
+PACKAGECONFIG_OPENVX:mx8-nxp-bsp:imxgpu = "openvx"
+PACKAGECONFIG_OPENVX:mx8mm-nxp-bsp      = ""
+# The tensorflow-lite implementation for 8ULP uses CPU, and so doesn't
+# support OpenVX
+PACKAGECONFIG_OPENVX:mx8ulp-nxp-bsp     = ""
+
+PACKAGECONFIG[openvx] = ",,,libopenvx-imx"
+
+do_install () {
+    install -d ${D}${bindir}
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    install -d ${D}/${PYTHON_SITEPACKAGES_DIR}
+
+    cp -r  ${S}/modelrunner/bin/* ${D}${bindir}
+    cp -rP ${S}/modelrunner/lib/* ${D}${libdir}
+    cp -rP ${S}/${BPN}/lib/* ${D}${libdir}
+    cp -r  ${S}/${BPN}/include/* ${D}${includedir}
+    if ${@bb.utils.contains('PACKAGECONFIG', 'openvx', 'false', 'true', d)} ; then
+        rm ${D}${libdir}/deepview-rt-openvx.so
+    fi
+ 
+    ${STAGING_BINDIR_NATIVE}/pip3 install --disable-pip-version-check -v \
+        -t ${D}/${PYTHON_SITEPACKAGES_DIR} --no-cache-dir --no-deps \
+        ${S}/whl/deepview_rt-*.whl
+
+    chown -R root:root "${D}"
+}
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+FILES_SOLIBSDEV = ""
+
+FILES:${PN} += "${libdir}/*"
+RDEPENDS:${PN} = "onnxruntime tensorflow-lite"
+INSANE_SKIP:${PN} += "dev-so dev-deps ldflags"
+
+BBCLASSEXTEND = "nativesdk"
+
+COMPATIBLE_MACHINE = "(mx8-nxp-bsp|mx9-nxp-bsp)"