hardknott: isp-imx: sync with meta-imx hardknott-5.10.72-2.2.0 branch

These recipes are exclusive to the i.MX8MP, so add them just in case.

Signed-off-by: Gabriel Valcazar <gabriel.valcazar@digi.com>

meta-digi-arm/recipes-bsp/isp-imx/basler-camera_4.2.2.16.0.bb

@@ -0,0 +1,27 @@
+# Copyright 2020-2021 NXP
+
+DESCRIPTION = "Basler camera binary drivers"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=03bcadc8dc0a788f66ca9e2b89f56c6f"
+
+inherit fsl-eula-unpack
+
+SRC_URI = "${FSL_MIRROR}/${BPN}-${PV}.bin;fsl-eula=true"
+
+SRC_URI[md5sum] = "489763169857773bade28611e649172e"
+SRC_URI[sha256sum] = "3d4ae594659a697eef7479ca2480cc53f1d460f22bcc1c58104cff63bc6705fe"
+
+do_install() {
+    dest_dir=${D}/opt/imx8-isp/bin
+    install -d ${D}/${libdir}
+    install -d $dest_dir
+    cp -r ${S}/opt/imx8-isp/bin/* $dest_dir
+    cp -r ${S}/usr/lib/* ${D}/${libdir}
+}
+
+SYSTEMD_AUTO_ENABLE = "enable"
+
+FILES_${PN} = "${libdir} /opt"
+INSANE_SKIP_${PN} = "file-rdeps already-stripped"
+
+COMPATIBLE_MACHINE = "(mx8mp)"

meta-digi-arm/recipes-bsp/isp-imx/isp-imx_4.2.2.16.0.bb

@@ -0,0 +1,80 @@
+# Copyright 2020-2021 NXP
+
+DESCRIPTION = "i.MX Verisilicon Software ISP"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=03bcadc8dc0a788f66ca9e2b89f56c6f"
+
+DEPENDS = "python3 libdrm virtual/libg2d libtinyxml2"
+
+SRC_URI = "${FSL_MIRROR}/${BP}.bin;fsl-eula=true"
+SRC_URI[md5sum] = "f490153dbec234a04416ad41834806b2"
+SRC_URI[sha256sum] = "83b24b9d1f7a40a506a45a1c5c2ef2ca2313fe9b23fde591e3b7dce77ea359ca"
+
+inherit fsl-eula-unpack cmake systemd use-imx-headers
+
+# Build the sub-folder appshell
+OECMAKE_SOURCEPATH = "${S}/appshell"
+
+# Use make instead of ninja
+OECMAKE_GENERATOR = "Unix Makefiles"
+
+SYSTEMD_SERVICE_${PN} = "imx8-isp.service"
+
+EXTRA_OECMAKE += " \
+    -DSDKTARGETSYSROOT=${STAGING_DIR_HOST} \
+    -DCMAKE_BUILD_TYPE=release \
+    -DISP_VERSION=ISP8000NANO_V1802 \
+    -DPLATFORM=ARM64 \
+    -DAPPMODE=V4L2 \
+    -DQTLESS=1 \
+    -DFULL_SRC_COMPILE=1 \
+    -DWITH_DRM=1 \
+    -DWITH_DWE=1 \
+    -DSERVER_LESS=1 \
+    -DSUBDEV_V4L2=1 \
+    -DENABLE_IRQ=1 \
+    -DPARTITION_BUILD=0 \
+    -D3A_SRC_BUILD=0 \
+    -DIMX_G2D=ON \
+    -Wno-dev \
+"
+
+do_install() {
+    install -d ${D}/${libdir}
+    install -d ${D}/${includedir}
+    install -d ${D}/opt/imx8-isp/bin
+
+    cp -r ${WORKDIR}/build/generated/release/bin/*_test ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/bin/*2775* ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/bin/isp_media_server ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/bin/vvext ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/lib/*.so* ${D}/${libdir}
+    cp -r ${WORKDIR}/build/generated/release/include/* ${D}/${includedir}
+
+    cp ${WORKDIR}/${BP}/imx/run.sh ${D}/opt/imx8-isp/bin
+    cp ${WORKDIR}/${BP}/imx/start_isp.sh ${D}/opt/imx8-isp/bin
+
+    chmod +x ${D}/opt/imx8-isp/bin/run.sh
+    chmod +x ${D}/opt/imx8-isp/bin/start_isp.sh
+
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+      install -d ${D}${systemd_system_unitdir}
+      install -m 0644 ${WORKDIR}/${BP}/imx/imx8-isp.service ${D}${systemd_system_unitdir}
+    fi
+}
+
+# The build contains a mix of versioned and unversioned libraries, so
+# the default packaging configuration needs some modifications
+FILES_SOLIBSDEV = ""
+FILES_${PN} += "/opt ${libdir}/lib*${SOLIBSDEV}"
+FILES_${PN}-dev += " \
+    ${libdir}/libjsoncpp.so \
+    ${libdir}/libos08a20.so \
+    ${libdir}/libov2775.so \
+"
+
+INSANE_SKIP_${PN} = "rpaths"
+
+RDEPENDS_${PN} = "libdrm libpython3 bash"
+
+COMPATIBLE_MACHINE = "(mx8mp)"