qt4: integrate deprecated fsl-gui-extrafiles package

This package was used in 'meta-fsl-demos' layer, but was deprecated and
removed. It includes desktop launchers for QT4 demo/example apps. We
still show those demo apps, so integrate the launchers directly into a
qt4 bbappend.

https://jira.digi.com/browse/DEL-1164

Signed-off-by: Javier Viguera <javier.viguera@digi.com>

meta-digi-dey/recipes-graphics/fsl-gui-extrafiles/fsl-gui-extrafiles.bb

@@ -1,32 +0,0 @@
-# Copyright (C) 2012-2013 Freescale Semiconductor
-
-DESCRIPTION = "Extra files for fsl-gui-image"
-LICENSE = "LGPLv2"
-PR = "r6"
-S="${WORKDIR}"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=dfb0b24e10ca72d739b14d769d91cf9b"
-
-SRC_URI += "file://qtbrowser.desktop \
-            file://webkit.png \
-            file://qtmediaplayer.desktop \
-            file://qtmediaplayer.png \
-            file://qtdemo.desktop \
-            file://qtdemo.png \
-            file://qthellogles2.desktop \
-            file://hellogl_es2.png \
-            file://LICENSE"
-
-inherit allarch
-
-do_install () {
-    install -d ${D}/${datadir}/pixmaps
-    install -d ${D}/${datadir}/applications
-    install -m 0644 ${WORKDIR}/webkit.png ${D}/${datadir}/pixmaps
-    install -m 0644 ${WORKDIR}/qtbrowser.desktop ${D}/${datadir}/applications
-    install -m 0644 ${WORKDIR}/qtmediaplayer.png ${D}/${datadir}/pixmaps
-    install -m 0644 ${WORKDIR}/qtmediaplayer.desktop ${D}/${datadir}/applications
-    install -m 0644 ${WORKDIR}/qtdemo.png ${D}/${datadir}/pixmaps
-    install -m 0644 ${WORKDIR}/qtdemo.desktop ${D}/${datadir}/applications
-    install -m 0644 ${WORKDIR}/hellogl_es2.png ${D}/${datadir}/pixmaps
-    install -m 0644 ${WORKDIR}/qthellogles2.desktop ${D}/${datadir}/applications
-}

meta-digi-dey/recipes-graphics/fsl-gui-extrafiles/fsl-gui-extrafiles/LICENSE

@@ -1 +0,0 @@
-All content inside fsl-gui-extrafiles package are distributed under GPLv2 license

meta-digi-dey/recipes-graphics/packagegroups/packagegroup-dey-qt.bb

@@ -15,5 +15,4 @@ RDEPENDS_${PN} = "\
 	qt4-plugin-phonon-backend-gstreamer \
 	qt4-demos \
 	qt4-examples \
-	fsl-gui-extrafiles \
 "

meta-digi-dey/recipes-qt/qt4/qt4-x11-free/qtdemo.desktop

@@ -1,5 +1,5 @@
 [Desktop Entry]
-Name=QT Demo Launcher 
+Name=QT Demo Launcher
 Exec=/usr/bin/qtdemo
 Icon=qtdemo
 Terminal=false

meta-digi-dey/recipes-qt/qt4/qt4-x11-free_%.bbappend

@@ -0,0 +1,62 @@
+# Copyright (C) 2014 Digi International
+#
+# Desktop launchers for QT4 demo/example apps
+#
+# Origin: fsl-gui-extrafiles package (which was removed from meta-fsl-demos)
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+SRC_URI += " \
+    file://qtbrowser.desktop \
+    file://qtdemo.desktop \
+    file://qthellogles2.desktop \
+    file://qtmediaplayer.desktop \
+    file://hellogl_es2.png \
+    file://qtdemo.png \
+    file://qtmediaplayer.png \
+    file://webkit.png \
+"
+
+# Disable OpenGL for ccardimx28
+QT_GLFLAGS_ccardimx28 = "-no-opengl"
+
+do_install_append() {
+    install -d ${D}${datadir}/applications ${D}${datadir}/pixmaps
+    install -m 0644 ${WORKDIR}/qtbrowser.desktop ${D}${datadir}/applications
+    install -m 0644 ${WORKDIR}/qtdemo.desktop ${D}${datadir}/applications
+    install -m 0644 ${WORKDIR}/qtmediaplayer.desktop ${D}${datadir}/applications
+    install -m 0644 ${WORKDIR}/qtdemo.png ${D}${datadir}/pixmaps
+    install -m 0644 ${WORKDIR}/qtmediaplayer.png ${D}${datadir}/pixmaps
+    install -m 0644 ${WORKDIR}/webkit.png ${D}${datadir}/pixmaps
+}
+
+do_install_append_ccimx5() {
+    install -m 0644 ${WORKDIR}/qthellogles2.desktop ${D}${datadir}/applications
+    install -m 0644 ${WORKDIR}/hellogl_es2.png ${D}${datadir}/pixmaps
+}
+
+do_install_append_ccimx6() {
+    install -m 0644 ${WORKDIR}/qthellogles2.desktop ${D}${datadir}/applications
+    install -m 0644 ${WORKDIR}/hellogl_es2.png ${D}${datadir}/pixmaps
+}
+
+FILES_${QT_BASE_NAME}-demos += " \
+    ${datadir}/applications/qtbrowser.desktop \
+    ${datadir}/applications/qtdemo.desktop \
+    ${datadir}/applications/qtmediaplayer.desktop \
+    ${datadir}/pixmaps/qtdemo.png \
+    ${datadir}/pixmaps/qtmediaplayer.png \
+    ${datadir}/pixmaps/webkit.png \
+"
+
+FILES_${QT_BASE_NAME}-examples_append_ccimx5 = " \
+    ${datadir}/applications/qthellogles2.desktop \
+    ${datadir}/pixmaps/hellogl_es2.png \
+"
+
+FILES_${QT_BASE_NAME}-examples_append_ccimx6 = " \
+    ${datadir}/applications/qthellogles2.desktop \
+    ${datadir}/pixmaps/hellogl_es2.png \
+"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"