From 98a16a31d6cf68e4f90d84880b9beb145ebcb224 Mon Sep 17 00:00:00 2001
From: Mike Engel <Mike.Engel@digi.com>
Date: Wed, 1 Jul 2020 14:21:13 +0200
Subject: [PATCH] recipes-bsp: imx-aft: Update recipes to new BSP release
 imx-5.4.24-2.1.0.

Signed-off-by: Mike Engel <Mike.Engel@digi.com>
---
 .../recipes-bsp/imx-atf/imx-atf_2.0.bbappend  | 34 ----------
 .../recipes-bsp/imx-atf/imx-atf_2.2.bb        | 64 +++++++++++++++++++
 2 files changed, 64 insertions(+), 34 deletions(-)
 delete mode 100644 meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.0.bbappend
 create mode 100644 meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.2.bb

diff --git a/meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.0.bbappend b/meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.0.bbappend
deleted file mode 100644
index 3d86ccc5a..000000000
--- a/meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.0.bbappend
+++ /dev/null
@@ -1,34 +0,0 @@
-FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
-
-SRCBRANCH = "imx_5.4.3_2.0.0"
-ATF_SRC ?= "git://source.codeaurora.org/external/imx/imx-atf.git;protocol=https"
-SRC_URI = "${ATF_SRC};branch=${SRCBRANCH} \
-           file://0001-Allow-BUILD_STRING-to-be-set-in-.revision-file.patch \
-"
-SRCREV = "f1a195b5cce64365a7227557a9009a4f545aa02d"
-
-SRC_URI_append_ccimx8mn = " file://0001-imx8mn-Disable-M7-debug-console.patch"
-
-PLATFORM_mx8x   = "imx8qx"
-# Override PLATFORM_mx8qxp from the included recipe
-PLATFORM_mx8qxp = "imx8qx"
-PLATFORM_mx8mn  = "imx8mn"
-PLATFORM_mx8mp  = "imx8mp"
-PLATFORM_imx8dxlevk = "imx8dxl"
-PLATFORM_mx8dxlevk-phantom = "imx8qx"
-PLATFORM_mx8dx = "imx8dx"
-
-BUILD_OPTEE = "${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'true', 'false', d)}"
-
-do_compile_append() {
-    if [ "${BUILD_OPTEE}" = "true" ]; then
-        oe_runmake clean BUILD_BASE=build-optee
-        oe_runmake BUILD_BASE=build-optee SPD=opteed bl31
-    fi
-}
-
-do_deploy_append () {
-    if [ "${BUILD_OPTEE}" = "true" ]; then
-        install -m 0644 ${S}/build-optee/${PLATFORM}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${PLATFORM}.bin-optee
-    fi
-}
diff --git a/meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.2.bb b/meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.2.bb
new file mode 100644
index 000000000..3867fe927
--- /dev/null
+++ b/meta-digi-arm/recipes-bsp/imx-atf/imx-atf_2.2.bb
@@ -0,0 +1,64 @@
+# Copyright (C) 2017-2020 NXP
+
+DESCRIPTION = "i.MX ARM Trusted Firmware"
+SECTION = "BSP"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
+
+PV .= "+git${SRCPV}"
+
+SRCBRANCH = "imx_5.4.24_2.1.0"
+ATF_SRC ?= "git://source.codeaurora.org/external/imx/imx-atf.git;protocol=https"
+SRC_URI = "${ATF_SRC};branch=${SRCBRANCH} \
+"
+SRCREV = "b0a00f22b09c13572d3e87902a1069dee34763bd"
+
+SRC_URI_append_ccimx8mn = " file://0001-imx8mn-Disable-M7-debug-console.patch"
+
+S = "${WORKDIR}/git"
+
+inherit deploy
+
+BOOT_TOOLS = "imx-boot-tools"
+
+PLATFORM        ?= "INVALID"
+PLATFORM_imx8dxlevk = "imx8dxl"
+PLATFORM_mx8dx  = "imx8dx"
+PLATFORM_mx8dxlevk-phantom = "imx8qx"
+PLATFORM_mx8mm  = "imx8mm"
+PLATFORM_mx8mn  = "imx8mn"
+PLATFORM_mx8mp  = "imx8mp"
+PLATFORM_mx8mq  = "imx8mq"
+PLATFORM_mx8qm  = "imx8qm"
+PLATFORM_mx8x   = "imx8qx"
+
+
+EXTRA_OEMAKE += " \
+    CROSS_COMPILE="${TARGET_PREFIX}" \
+    PLAT=${PLATFORM} \
+"
+
+BUILD_OPTEE = "${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'true', 'false', d)}"
+
+do_compile() {
+    # Clear LDFLAGS to avoid the option -Wl recognize issue
+    unset LDFLAGS
+    oe_runmake bl31
+    if ${BUILD_OPTEE}; then
+       oe_runmake clean BUILD_BASE=build-optee
+       oe_runmake BUILD_BASE=build-optee SPD=opteed bl31
+    fi
+}
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    install -Dm 0644 ${S}/build/${PLATFORM}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${PLATFORM}.bin
+    if ${BUILD_OPTEE}; then
+       install -m 0644 ${S}/build-optee/${PLATFORM}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${PLATFORM}.bin-optee
+    fi
+}
+addtask deploy after do_compile
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(mx8)"