diff --git a/meta-digi-arm/conf/machine/include/imx-digi-base.inc b/meta-digi-arm/conf/machine/include/imx-digi-base.inc
index c4748e379..f0ea6bc5a 100644
--- a/meta-digi-arm/conf/machine/include/imx-digi-base.inc
+++ b/meta-digi-arm/conf/machine/include/imx-digi-base.inc
@@ -280,6 +280,8 @@ PREFERRED_VERSION_optee-test:mx9-nxp-bsp   ??= "3.19.0.imx"
 
 # Machine learning backports from NXP's lf-6.1.1_1.0.0 release
 PREFERRED_VERSION_deepview-rt:ccimx93 = "2.4.46.1-aarch64"
+PREFERRED_VERSION_flatbuffers:ccimx93 = "2.0.7"
+PREFERRED_VERSION_flatbuffers-native:ccimx93 = "2.0.7"
 PREFERRED_VERSION_tensorflow-lite:ccimx93 = "2.10.0"
 PREFERRED_VERSION_tensorflow-lite-host-tools:ccimx93 = "2.10.0"
 PREFERRED_VERSION_tensorflow-lite-host-tools-native:ccimx93 = "2.10.0"
diff --git a/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/files/flatbuffers.pc.in b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/files/flatbuffers.pc.in
new file mode 100644
index 000000000..3a0666c3e
--- /dev/null
+++ b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/files/flatbuffers.pc.in
@@ -0,0 +1,7 @@
+Name: flatbuffers
+Description: memory efficient serialization library
+Version:  @version@
+Requires:
+Libs: -L@libdir@ -lflatbuffers
+Cflags: -I@includedir@
+
diff --git a/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/flatbuffers_2.%.bbappend b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/flatbuffers_2.%.bbappend
new file mode 100644
index 000000000..b7c5e09a5
--- /dev/null
+++ b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/flatbuffers_2.%.bbappend
@@ -0,0 +1,11 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+SRC_URI:append = " file://flatbuffers.pc.in"
+
+do_install:append() {
+    install -D -m 0644 ${WORKDIR}/flatbuffers.pc.in ${D}${libdir}/pkgconfig/flatbuffers.pc
+    sed -i 's:@version@:${PV}:g
+        s:@libdir@:${libdir}:g
+        s:@includedir@:${includedir}:g' ${D}${libdir}/pkgconfig/flatbuffers.pc
+}
+
diff --git a/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/flatbuffers_2.0.7.bb b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/flatbuffers_2.0.7.bb
new file mode 100644
index 000000000..1fe5facda
--- /dev/null
+++ b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/flatbuffers_2.0.7.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Memory Efficient Serialization Library"
+HOMEPAGE = "https://github.com/google/flatbuffers"
+SECTION = "console/tools"
+LICENSE = "Apache-2.0"
+
+PACKAGE_BEFORE_PN = "${PN}-compiler"
+DEPENDS = "flatbuffers-native"
+
+RDEPENDS:${PN}-compiler = "${PN}"
+RDEPENDS:${PN}-${PYTHON_PN} = "${PN}"
+RDEPENDS:${PN}-dev += "${PN}-compiler"
+
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRCREV = "8367664f15c3ea2ee58c67dacf9d630b49466de5"
+
+SRC_URI = "git://github.com/google/flatbuffers.git;branch=master;protocol=https"
+
+CVE_CHECK_IGNORE += "CVE-2020-35864"
+
+EXTRA_OECMAKE += "\
+    -DFLATBUFFERS_BUILD_TESTS=OFF \    
+    -DFLATBUFFERS_BUILD_SHAREDLIB=ON \
+"
+
+EXTRA_OECMAKE:append:class-target = " -DFLATBUFFERS_FLATC_EXECUTABLE=${STAGING_BINDIR_NATIVE}/flatc"
+
+inherit cmake python3native
+
+S = "${WORKDIR}/git"
+
+FILES:${PN}-compiler = "${bindir}"
+
+BBCLASSEXTEND = "native nativesdk"
diff --git a/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/python3-flatbuffers_2.0.7.bb b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/python3-flatbuffers_2.0.7.bb
new file mode 100644
index 000000000..151aa793b
--- /dev/null
+++ b/meta-digi-dey/dynamic-layers/meta-ml/recipes-devtools/flatbuffers/python3-flatbuffers_2.0.7.bb
@@ -0,0 +1,14 @@
+SUMMARY = "Memory Efficient Serialization Library - Python3 Modules"
+HOMEPAGE = "https://github.com/google/flatbuffers"
+SECTION = "console/tools"
+LICENSE = "Apache-2.0"
+
+LIC_FILES_CHKSUM = "file://../LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRCREV = "8367664f15c3ea2ee58c67dacf9d630b49466de5"
+SRC_URI = "git://github.com/google/flatbuffers.git;branch=master;protocol=https"
+S = "${WORKDIR}/git/python"
+
+RDEPENDS:${PN} = "flatbuffers"
+
+inherit setuptools3
\ No newline at end of file