From a8d8aeade8e24f9318afc27470987c82905b96ee Mon Sep 17 00:00:00 2001
From: Isaac Hermida <isaac.hermida@digi.com>
Date: Tue, 5 May 2026 14:23:44 +0200
Subject: [PATCH] cc-container-mng: switch to proprietary 1.0.0 tarball source

The package is no longer fetched from Git, so rename the recipe to a
versioned .bb file and fetch the proprietary artifact from Digi server.

Signed-off-by: Isaac Hermida <isaac.hermida@digi.com>
---
 .../cc-container-mng_1.0.0.bb                 | 77 +++++++++++++++++++
 .../cc-container-mng/cc-container-mng_git.bb  | 58 --------------
 .../cc-container-mng/files/cc-containerctl    |  5 ++
 .../cc-container-mng/files/cc-containerd      |  5 ++
 4 files changed, 87 insertions(+), 58 deletions(-)
 create mode 100644 meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_1.0.0.bb
 delete mode 100644 meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb
 create mode 100644 meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerctl
 create mode 100644 meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd

diff --git a/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_1.0.0.bb b/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_1.0.0.bb
new file mode 100644
index 000000000..13386356d
--- /dev/null
+++ b/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_1.0.0.bb
@@ -0,0 +1,77 @@
+# Copyright (C) 2026, Digi International Inc.
+
+SUMMARY = "Digi ConnectCore Container Manager daemon and CLI"
+DESCRIPTION = "Local daemon and CLI to manage Podman/LXC container lifecycle on ConnectCore devices."
+SECTION = "base"
+
+LICENSE = "CLOSED"
+
+CC_CONTAINER_WHEEL = "digi_cc_container-${PV}-py3-none-any.whl"
+
+SRC_URI = " \
+    ${DIGI_PKG_SRC}/${BP}.tar.gz;name=archive \
+    file://cc-containerd \
+    file://cc-containerctl \
+    file://cc-containerd.service \
+    file://cc-containerd-shutdown.service \
+"
+SRC_URI[archive.md5sum] = "4429f2178682a57198d35a208c5eff4b"
+SRC_URI[archive.sha256sum] = "fed41d48b422f9af4f681c5b0457140f33edd177cf974fdec935e1c6ffeb128c"
+
+S = "${WORKDIR}/${BP}"
+
+inherit python3native python3-dir systemd
+
+SYSTEMD_SERVICE:${PN} = "cc-containerd.service cc-containerd-shutdown.service"
+SYSTEMD_AUTO_ENABLE ?= "enable"
+
+DEPENDS += "python3-pip-native"
+
+RDEPENDS:${PN} += " \
+    python3-core \
+    python3-asyncio \
+    python3-json \
+    python3-logging \
+"
+
+do_install() {
+    nativepython3 -m pip install \
+        --no-deps \
+        --no-index \
+        --no-compile \
+        --root=${D} \
+        --prefix=${prefix} \
+        ${S}/${CC_CONTAINER_WHEEL}
+
+    rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/digi_cc_container-${PV}.dist-info/direct_url.json
+
+    install -d ${D}${bindir}
+    install -m 0755 ${WORKDIR}/cc-containerd ${D}${bindir}/cc-containerd
+    install -m 0755 ${WORKDIR}/cc-containerctl ${D}${bindir}/cc-containerctl
+
+    install -d ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/cc-containerd.service \
+        ${D}${systemd_system_unitdir}/cc-containerd.service
+    install -m 0644 ${WORKDIR}/cc-containerd-shutdown.service \
+        ${D}${systemd_system_unitdir}/cc-containerd-shutdown.service
+
+    install -d ${D}${sysconfdir}
+    install -m 0644 ${S}/cc-container-mng.conf \
+        ${D}${sysconfdir}/cc-container-mng.conf
+
+    sed -i \
+        -e "s|\"/opt/cc-container|\"${CC_CONTAINER_PATH}|g" \
+        ${D}${sysconfdir}/cc-container-mng.conf
+}
+
+FILES:${PN}:append = " \
+    ${bindir}/cc-containerd \
+    ${bindir}/cc-containerctl \
+    ${PYTHON_SITEPACKAGES_DIR}/digi \
+    ${PYTHON_SITEPACKAGES_DIR}/digi_cc_container-*.dist-info \
+    ${systemd_system_unitdir}/cc-containerd.service \
+    ${systemd_system_unitdir}/cc-containerd-shutdown.service \
+    ${sysconfdir}/cc-container-mng.conf \
+"
+
+CONFFILES:${PN} += "${sysconfdir}/cc-container-mng.conf"
diff --git a/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb b/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb
deleted file mode 100644
index d0574a383..000000000
--- a/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb
+++ /dev/null
@@ -1,58 +0,0 @@
-# Copyright (C) 2026, Digi International Inc.
-
-SUMMARY = "Digi ConnectCore Container Manager daemon and CLI"
-DESCRIPTION = "Local daemon and CLI to manage Podman/LXC container lifecycle on ConnectCore devices."
-HOMEPAGE = "https://github.com/digi-embedded/cc-container-mng"
-SECTION = "base"
-
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=266029e5b51b2fa808364134ee8ec673"
-
-SRCBRANCH ?= "master"
-SRCREV = "${AUTOREV}"
-PV = "0.1.0+git${SRCPV}"
-
-CC_CONTAINER_MNG_URI_STASH = "${DIGI_MTK_GIT}/dey/cc-container-mng.git;protocol=ssh"
-CC_CONTAINER_MNG_URI_GITHUB = "${DIGI_GITHUB_GIT}/cc-container-mng.git;protocol=https"
-CC_CONTAINER_MNG_GIT_URI ?= "${@oe.utils.conditional('DIGI_INTERNAL_GIT', '1', '${CC_CONTAINER_MNG_URI_STASH}', '${CC_CONTAINER_MNG_URI_GITHUB}', d)}"
-
-SRC_URI = " \
-    ${CC_CONTAINER_MNG_GIT_URI};branch=${SRCBRANCH} \
-    file://cc-containerd.service \
-    file://cc-containerd-shutdown.service \
-"
-
-S = "${WORKDIR}/git"
-
-inherit python_setuptools_build_meta systemd
-
-SYSTEMD_SERVICE:${PN} = "cc-containerd.service cc-containerd-shutdown.service"
-SYSTEMD_AUTO_ENABLE ?= "enable"
-
-RDEPENDS:${PN} += " \
-    python3-core \
-    python3-asyncio \
-    python3-json \
-    python3-logging \
-"
-
-do_install:append() {
-    install -d ${D}${systemd_system_unitdir}
-    install -m 0644 ${WORKDIR}/cc-containerd.service ${D}${systemd_system_unitdir}/cc-containerd.service
-    install -m 0644 ${WORKDIR}/cc-containerd-shutdown.service ${D}${systemd_system_unitdir}/cc-containerd-shutdown.service
-
-    install -d ${D}${sysconfdir}
-    install -m 0644 ${S}/cc-container-mng.conf ${D}${sysconfdir}/cc-container-mng.conf
-
-    sed -i \
-        -e "s|\"/opt/cc-container|\"${CC_CONTAINER_PATH}|g" \
-        ${D}${sysconfdir}/cc-container-mng.conf
-}
-
-FILES:${PN}:append = " \
-    ${systemd_system_unitdir}/cc-containerd.service \
-    ${systemd_system_unitdir}/cc-containerd-shutdown.service \
-    ${sysconfdir}/cc-container-mng.conf \
-"
-
-CONFFILES:${PN} += "${sysconfdir}/cc-container-mng.conf"
diff --git a/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerctl b/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerctl
new file mode 100644
index 000000000..cc65fd4ba
--- /dev/null
+++ b/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerctl
@@ -0,0 +1,5 @@
+#!/usr/bin/python3
+from digi.container.cli import main
+
+if __name__ == "__main__":
+    raise SystemExit(main())
diff --git a/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd b/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd
new file mode 100644
index 000000000..7a6a95958
--- /dev/null
+++ b/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd
@@ -0,0 +1,5 @@
+#!/usr/bin/python3
+from digi.container.daemon import main
+
+if __name__ == "__main__":
+    raise SystemExit(main())