meta-digi-arm: Add recipes-graphics, amd-gpu-bin and libz160.

A difference with meta-fsl-arm is that we include then non X11 version.

Signed-off-by: Alex Gonzalez <alex.gonzalez@digi.com>

meta-digi-arm/conf/machine/include/imx-base.inc

@@ -41,10 +41,7 @@ MACHINE_EXTRA_RRECOMMENDS += "imx-audio \
 # Gstreamer plugin
 MACHINE_GSTREAMER_PLUGIN ?= "gst-fsl-plugin"
 
-# [DIGI] TODO This may be amd-gpu-bin-mx51
+PREFERRED_PROVIDER_virtual/libgl_mx5 ?= "${@base_contains('DISTRO_FEATURES', 'x11', 'amd-gpu-x11-bin-mx51', 'amd-gpu-bin-mx51', d)}"
-PREFERRED_PROVIDER_virtual/egl_mx5 ?= "amd-gpu-x11-bin-mx51"
-PREFERRED_PROVIDER_virtual/libgles1_mx5 ?= "amd-gpu-x11-bin-mx51"
-PREFERRED_PROVIDER_virtual/libgles2_mx5 ?= "amd-gpu-x11-bin-mx51"
 
 EXTRA_IMAGEDEPENDS = "u-boot"
 

meta-digi-arm/recipes-graphics/amd-gpu-bin/amd-gpu-bin-mx51_11.09.01.bb

@@ -0,0 +1,104 @@
+# Copyright (C) 2011, 2012 Freescale
+# Copyright (C) 2012 Digi International
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "GPU driver and apps on mx5x"
+LICENSE = "Proprietary"
+SECTION = "libs"
+PR = "r11"
+
+#todo: Replace for correct AMD license
+LIC_FILES_CHKSUM = "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
+
+DEPENDS = "libz160"
+DEPENDS += "${@base_contains('DISTRO_FEATURES', 'x11', 'virtual/libx11', '', d)}"
+PROVIDES = "virtual/libgl"
+RDEPENDS = "libz160"
+
+SRC_URI = "${DIGI_LOG_MIRROR}/amd-gpu-bin-mx51-${PV}.tar.gz"
+SRC_URI[md5sum] = "15ede91135590fc12cc29a2bba46c12c"
+SRC_URI[sha256sum] = "c87ad4e0c721a10e9faed9e096e180b326162e342d41cdfc14c5119110bde0f4"
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${bindir}
+    install -d ${D}${includedir}
+
+    cp -axr ${S}/usr/bin/* ${D}${bindir}
+    cp -axf ${S}/usr/lib/* ${D}${libdir}
+    cp -axr ${S}/usr/include/* ${D}${includedir}
+
+    find ${D}${bindir} -type f -exec chmod 755 {} \;
+    find ${D}${libdir} -type f -exec chmod 644 {} \;
+    find ${D}${includedir} -type f -exec chmod 644 {} \;
+
+    # FIXME: Fix sonames of broken libraries
+    mv ${D}${libdir}/lib2dz160.so ${D}${libdir}/lib2dz160.so.0
+    mv ${D}${libdir}/lib2dz430.so ${D}${libdir}/lib2dz430.so.0
+
+    # FIXME: Remove unkown files
+    rm -r ${D}${libdir}/libcsi.a \
+          ${D}${libdir}/libres.a
+}
+
+PACKAGES =+ "libgsl-fsl-mx51 libgsl-fsl-mx51-dev libgsl-fsl-mx51-dbg \
+             libegl-mx51 libegl-mx51-dev libegl-mx51-dbg \
+             libgles-mx51 libgles-mx51-dev libgles-mx51-dbg \
+             libgles2-mx51 libgles2-mx51-dev libgles2-mx51-dbg \
+             libopenvg-mx51 libopenvg-mx51-dev libopenvg-mx51-dbg \
+             lib2dz160-mx51 lib2dz160-mx51-dbg \
+             lib2dz430-mx51 lib2dz430-mx51-dbg"
+
+INSANE_SKIP_${PN} = "ldflags"
+
+FILES_${PN}-dbg = "${bindir}/.debug/*"
+
+FILES_libgsl-fsl-mx51 = "${libdir}/libgsl-fsl${SOLIBS}"
+FILES_libgsl-fsl-mx51-dev = "${libdir}/libgsl-fsl${SOLIBSDEV}"
+FILES_libgsl-fsl-mx51-dbg = "${libdir}/.debug/libgsl-fsl${SOLIBS}"
+
+INSANE_SKIP_libgsl-fsl-mx51 = "ldflags"
+INSANE_SKIP_libgsl-fsl-mx51-dev = "ldflags"
+INSANE_SKIP_libgsl-fsl-mx51-dbg = "ldflags"
+
+FILES_libegl-mx51 = "${libdir}/libEGL${SOLIBS}"
+FILES_libegl-mx51-dev = "${includedir}/EGL ${includedir}/KHR ${libdir}/libEGL${SOLIBSDEV}"
+FILES_libegl-mx51-dbg = "${libdir}/.debug/libEGL${SOLIBS}"
+
+INSANE_SKIP_libegl-mx51 = "ldflags"
+INSANE_SKIP_libegl-mx51-dev = "ldflags"
+INSANE_SKIP_libegl-mx51-dbg = "ldflags"
+
+FILES_libgles-mx51 = "${libdir}/libGLESv1*${SOLIBS}"
+FILES_libgles-mx51-dev = "${includedir}/GLES ${libdir}/libGLESv1*${SOLIBSDEV}"
+FILES_libgles-mx51-dbg = "${libdir}/.debug/libGLESv1*${SOLIBS}"
+INSANE_SKIP_libgles-mx51 = "ldflags"
+INSANE_SKIP_libgles-mx51-dev = "ldflags"
+INSANE_SKIP_libgles-mx51-dbg = "ldflags"
+
+FILES_libgles2-mx51 = "${libdir}/libGLESv2${SOLIBS}"
+FILES_libgles2-mx51-dev = "${includedir}/GLES2 ${libdir}/libGLESv2${SOLIBSDEV}"
+FILES_libgles2-mx51-dbg = "${libdir}/.debug/libGLESv2${SOLIBS}"
+INSANE_SKIP_libgles2-mx51 = "ldflags"
+INSANE_SKIP_libgles2-mx51-dev = "ldflags"
+INSANE_SKIP_libgles2-mx51-dbg = "ldflags"
+
+FILES_libopenvg-mx51 = "${libdir}/libOpenVG${SOLIBS}"
+FILES_libopenvg-mx51-dev = "${includedir}/VG ${libdir}/libOpenVG${SOLIBSDEV}"
+FILES_libopenvg-mx51-dbg = "${libdir}/.debug/libOpenVG${SOLIBS}"
+INSANE_SKIP_libopenvg-mx51 = "ldflags"
+INSANE_SKIP_libopenvg-mx51-dev = "ldflags"
+INSANE_SKIP_libopenvg-mx51-dbg = "ldflags"
+
+FILES_lib2dz160-mx51 = "${libdir}/lib2dz160${SOLIBS}"
+FILES_lib2dz160-mx51-dbg = "${libdir}/.debug/lib2dz160${SOLIBS}"
+INSANE_SKIP_lib2dz160-mx51 = "ldflags"
+INSANE_SKIP_lib2dz160-mx51-dbg = "ldflags"
+
+FILES_lib2dz430-mx51 = "${libdir}/lib2dz430${SOLIBS}"
+FILES_lib2dz430-mx51-dbg = "${libdir}/.debug/lib2dz430${SOLIBS}"
+INSANE_SKIP_lib2dz430-mx51 = "ldflags"
+INSANE_SKIP_lib2dz430-mx51-dbg = "ldflags"
+
+COMPATIBLE_MACHINE = "(mx5)"
+PACKAGE_ARCH = "${MACHINE_ARCH}"

meta-digi-arm/recipes-graphics/amd-gpu-bin/libz160_11.09.01.bb

@@ -0,0 +1,30 @@
+# Copyright (C) 2011, 2012 Freescale
+# Copyright (C) 2012 Digi International
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "AMD libz160 gpu driver"
+LICENSE = "Proprietary"
+SECTION = "libs"
+PR = "r2"
+
+#todo: Replace for correct AMD license
+LIC_FILES_CHKSUM = "file://usr/include/z160.h;endline=28;md5=65dd44cd769091092f38e34cd52cc271"
+
+SRC_URI = "${DIGI_LOG_MIRROR}/libz160-bin-${PV}.tar.gz"
+SRC_URI[md5sum] = "49b6d51e2ea6651107b08f43715c8c2e"
+SRC_URI[sha256sum] = "43b1bebb2656d0c868c10f66ddc064c6324b74694daedfb3f542f93f438232c5"
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    install -m 0755 ${S}/usr/lib/* ${D}${libdir}
+    install -m 0644 ${S}/usr/include/* ${D}${includedir}
+}
+
+S = "${WORKDIR}/${PN}-bin-${PV}"
+
+# Avoid QA Issue: No GNU_HASH in the elf binary
+INSANE_SKIP_${PN} = "ldflags"
+INSANE_SKIP_${PN}-dev = "ldflags"
+FILES_${PN} = "${libdir}/*.so"
+FILES_${PN}-dev = "${includedir}"