From d721721567808626f5e729a833f05e96ca392439 Mon Sep 17 00:00:00 2001
From: Isaac Hermida <isaac.hermida@digi.com>
Date: Wed, 11 Mar 2026 14:38:30 +0100
Subject: [PATCH] meta-digi-containers: add cc-container-mng daemon recipe

Add the cc-container-mng recipe and systemd service.

https://onedigi.atlassian.net/browse/DEL-10005

Signed-off-by: Isaac Hermida <isaac.hermida@digi.com>
---
 .../cc-container-mng/cc-container-mng_git.bb  | 51 +++++++++++++++++++
 .../files/cc-containerd.service               | 13 +++++
 2 files changed, 64 insertions(+)
 create mode 100644 meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb
 create mode 100644 meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd.service

diff --git a/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb b/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb
new file mode 100644
index 000000000..e59662d65
--- /dev/null
+++ b/meta-digi-containers/recipes-containers/cc-container-mng/cc-container-mng_git.bb
@@ -0,0 +1,51 @@
+# Copyright (C) 2026, Digi International Inc.
+
+SUMMARY = "Digi ConnectCore Container Manager daemon and CLI"
+DESCRIPTION = "Local daemon and CLI to manage Podman/LXC container lifecycle on ConnectCore devices."
+HOMEPAGE = "https://github.com/digi-embedded/cc-container-mng"
+SECTION = "base"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=b9f6fb44826f22358130c433cdf487a0"
+
+SRCBRANCH ?= "master"
+SRCREV = "${AUTOREV}"
+PV = "0.1.0+git${SRCPV}"
+
+CC_CONTAINER_MNG_URI_STASH = "${DIGI_MTK_GIT}/dey/cc-container-mng.git;protocol=ssh"
+CC_CONTAINER_MNG_URI_GITHUB = "${DIGI_GITHUB_GIT}/cc-container-mng.git;protocol=https"
+CC_CONTAINER_MNG_GIT_URI ?= "${@oe.utils.conditional('DIGI_INTERNAL_GIT', '1', '${CC_CONTAINER_MNG_URI_STASH}', '${CC_CONTAINER_MNG_URI_GITHUB}', d)}"
+
+SRC_URI = " \
+    ${CC_CONTAINER_MNG_GIT_URI};branch=${SRCBRANCH} \
+    file://cc-containerd.service \
+"
+
+S = "${WORKDIR}/git"
+
+inherit python_setuptools_build_meta systemd
+
+SYSTEMD_SERVICE:${PN} = "cc-containerd.service"
+SYSTEMD_AUTO_ENABLE ?= "enable"
+
+RDEPENDS:${PN} += " \
+    python3-core \
+    python3-asyncio \
+    python3-json \
+    python3-logging \
+"
+
+do_install:append() {
+    install -d ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/cc-containerd.service ${D}${systemd_system_unitdir}/cc-containerd.service
+
+    install -d ${D}${sysconfdir}/cc-container
+    install -m 0644 ${S}/cc-container-mng.conf ${D}${sysconfdir}/cc-container/cc-container-mng.conf
+}
+
+FILES:${PN}:append = " \
+    ${systemd_system_unitdir}/cc-containerd.service \
+    ${sysconfdir}/cc-container/cc-container-mng.conf \
+"
+
+CONFFILES:${PN} += "${sysconfdir}/cc-container/cc-container-mng.conf"
diff --git a/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd.service b/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd.service
new file mode 100644
index 000000000..b47da7d90
--- /dev/null
+++ b/meta-digi-containers/recipes-containers/cc-container-mng/files/cc-containerd.service
@@ -0,0 +1,13 @@
+[Unit]
+Description=Digi ConnectCore Container Manager daemon
+After=network.target
+Wants=network.target
+
+[Service]
+Type=simple
+ExecStart=/usr/bin/cc-containerd --config-file /etc/cc-container/cc-container-mng.conf
+Restart=on-failure
+RestartSec=2
+
+[Install]
+WantedBy=multi-user.target