diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8.26.1.inc b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8.26.1.inc
deleted file mode 100644
index b7a035d91..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx-8.26.1.inc
+++ /dev/null
@@ -1,16 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017-2025 NXP
-# Copyright (C) 2018 O.S. Systems Software LTDA.
-SECTION = "base"
-LICENSE = "Proprietary"
-LIC_FILES_CHKSUM = "file://COPYING;md5=bc649096ad3928ec06a8713b8d787eac"
-
-# Note: This .inc file is used from differently named recipes, so the package
-# name must be hard-coded, i.e., ${BPN} cannot be used.
-SRC_URI = "${FSL_MIRROR}/firmware-imx-${PV}-${IMX_SRCREV_ABBREV}.bin;fsl-eula=true"
-IMX_SRCREV_ABBREV = "410be01"
-SRC_URI[sha256sum] = "0c2e2136c1efa544409017f14f07a1412cf8c1702075ed0e4060e903b91fe313"
-
-S = "${WORKDIR}/firmware-imx-${PV}-${IMX_SRCREV_ABBREV}"
-
-inherit fsl-eula-unpack
diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.26.1.bb b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.26.1.bb
deleted file mode 100644
index 2f3df4bd6..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/firmware-imx_8.26.1.bb
+++ /dev/null
@@ -1,171 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017-2021,2024-2025 NXP
-# Copyright (C) 2018 O.S. Systems Software LTDA.
-SUMMARY = "Freescale i.MX firmware"
-DESCRIPTION = "Freescale i.MX firmware such as for the VPU"
-
-require ${BP}.inc
-
-PE = "1"
-
-inherit allarch
-
-IMX_USE_LINUX_FIRMWARE_SDMA ?= "1"
-
-do_install() {
-    install -d ${D}${nonarch_base_libdir}/firmware/imx
-
-    # SDMA Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/sdma
-    install -m 0644 ${S}/firmware/sdma/* ${D}${nonarch_base_libdir}/firmware/imx/sdma
-    # Define IMX_USE_LINUX_FIRMWARE_SDMA = "0" in layer.conf, machine.conf, local.conf
-    # or in .bbappend to use sdma-imx6q/7d.bin from here and not linux-firmware
-    if [ ${IMX_USE_LINUX_FIRMWARE_SDMA} -gt 0 ]
-    then
-        rm -f ${D}${nonarch_base_libdir}/firmware/imx/sdma/sdma-imx6q.bin
-        rm -f ${D}${nonarch_base_libdir}/firmware/imx/sdma/sdma-imx7d.bin
-    fi
-
-    # EASRC Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/easrc
-    install -m 0644 ${S}/firmware/easrc/* ${D}${nonarch_base_libdir}/firmware/imx/easrc/
-
-    # XCVR Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/xcvr
-    install -m 0644 ${S}/firmware/xcvr/* ${D}${nonarch_base_libdir}/firmware/imx/xcvr/
-
-    # XUVI Firmware section
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/xuvi
-    install -m 0644 ${S}/firmware/xuvi/* ${D}${nonarch_base_libdir}/firmware/imx/xuvi/
-
-    # EPDC Firmware section
-    # NOTE:
-    # epdc_ED060XH2C1.fw file has .nonrestricted suffix in the source archive, hence it should
-    # be installed with a different name
-    install -d ${D}${nonarch_base_libdir}/firmware/imx/epdc
-    install -m 0644 ${S}/firmware/epdc/*.fw ${D}${nonarch_base_libdir}/firmware/imx/epdc/
-    install -m 0644 ${S}/firmware/epdc/epdc_ED060XH2C1.fw.nonrestricted ${D}${nonarch_base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw
-
-    # HDMI Firmware section
-    # NOTE:
-    # Only install pre-defined list of firmware files, since the source archive contains
-    # also HDMI binary files for imx8m derivatives, which are taken care of by another recipe
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${D}${nonarch_base_libdir}/firmware
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${D}${nonarch_base_libdir}/firmware
-    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${D}${nonarch_base_libdir}/firmware
-
-    # VPU Firmware section
-    # NOTE:
-    # Do the same thing as above for HDMI - only install a pre-defined list of firmware files,
-    # as some of other files are provided by packages from other recipes.
-    install -d ${D}${nonarch_base_libdir}/firmware/vpu
-    install -m 0644 ${S}/firmware/vpu/vpu_fw_imx*.bin ${D}${nonarch_base_libdir}/firmware/vpu
-    # Update i.MX8 vpu firmware path to align with kernel6.5+
-    install -d ${D}${nonarch_base_libdir}/firmware/amphion/vpu/
-    mv ${D}${nonarch_base_libdir}/firmware/vpu/vpu_fw_imx8* ${D}${nonarch_base_libdir}/firmware/amphion/vpu/
-    # Install i.MX 95 VPU firmware
-    install -m 0644 ${S}/firmware/vpu/wave633c_codec_fw.bin ${D}${nonarch_base_libdir}/firmware
-}
-
-#
-# This prepend is here to produce separate packages containing firmware,
-# which could be included separately based on the machine definition.
-#
-# It operates similar to the FILES mechanism by travesing through
-# ${D} + folder supplied as a first parameter, matches the regexp supplied
-# as second one, and for every file match - it creates a separate package,
-# which contains only files that matches the pattern.
-#
-python populate_packages:prepend() {
-    # CODA driver tries to locate VPU firmwares directly in ${nonarch_base_libdir}/firmware, to
-    # avoid fallback loading which is usually 40-60 seconds later after system boots up, let's
-    # create symbolic links in ${nonarch_base_libdir}/firmware for VPU firmwares.
-    def coda_vpu_links(file, pkg, pattern, format, basename):
-        # Only CODA VPU firmwares need this procedure
-        if 'imx8' in basename:
-            return
-
-        dir = os.path.dirname(file)
-        dir = os.path.abspath(os.path.join(dir, os.pardir))
-        cwd = os.getcwd()
-
-        os.chdir(dir)
-
-        name = os.path.basename(file)
-        os.symlink(os.path.join("vpu", name), name)
-
-        oldfiles = d.getVar('FILES:' + pkg)
-        newfile = os.path.join(d.getVar('nonarch_base_libdir'), "firmware", name)
-        d.setVar('FILES:' + pkg, oldfiles + " " + newfile)
-
-        os.chdir(cwd)
-
-
-    easrcdir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/easrc', d)
-    do_split_packages(d, easrcdir, '^easrc-([^_]*).*\.bin',
-                      output_pattern='firmware-imx-easrc-%s',
-                      description='Freescale IMX EASRC Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    vpudir = bb.data.expand('${nonarch_base_libdir}/firmware/vpu', d)
-    do_split_packages(d, vpudir, '^vpu_fw_([^_]*).*\.bin',
-                      output_pattern='firmware-imx-vpu-%s',
-                      description='Freescale IMX VPU Firmware [%s]',
-                      hook=coda_vpu_links,
-                      extra_depends='',
-                      prepend=True)
-
-    sdmadir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/sdma', d)
-    do_split_packages(d, sdmadir, '^sdma-([^-]*).*\.bin',
-                      output_pattern='firmware-imx-sdma-%s',
-                      description='Freescale IMX SDMA Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    xcvrdir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/xcvr', d)
-    do_split_packages(d, xcvrdir, '^xcvr-([^_]*).*\.bin',
-                      output_pattern='firmware-imx-xcvr-%s',
-                      description='Freescale IMX XCVR Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-
-    xuvidir = bb.data.expand('${nonarch_base_libdir}/firmware/imx/xuvi', d)
-    do_split_packages(d, xuvidir, '^vpu_fw_([^_]*).*\.bin',
-                      output_pattern='firmware-imx-xuvi-%s',
-                      description='Freescale IMX XUVI Firmware [%s]',
-                      extra_depends='',
-                      prepend=True)
-}
-
-# Declare a contract that we would provide packages produced by prepend above
-PACKAGES_DYNAMIC = "${PN}-vpu-* ${PN}-sdma-* ${PN}-easrc-* ${PN}-xcvr-* ${PN}-xuvi-*"
-
-#
-# Deal with the rest of Firmware packages here
-#
-# Provide EPDC and HDMI Firmware in common packages as they tend to be special in
-# terms of the content.
-#
-# NOTE: PACKAGES are defined explicitly here in order to remove the auto-generated
-# complimentary packages (-dev and -dbg).
-# This is done in order to be able to keep the main package empty and fail when
-# somebody tries to install it in the image.
-# If -dev package is present in that setup, and dev-pkgs is enabled in
-# IMAGE_FEATURES - this leads to a failure during do_rootfs() while all -dev
-# packages would be installed, and -dev package would fail because the main one
-# is empty.
-# Therefore, we opt-out from producing -dev package here, since also for firmware
-# files it makes no sense.
-PACKAGES = "${PN} ${PN}-epdc ${PN}-hdmi ${PN}-vpu-amphion ${PN}-vpu-wave"
-
-FILES:${PN}-epdc = "${nonarch_base_libdir}/firmware/imx/epdc/"
-FILES:${PN}-hdmi = " \
-    ${nonarch_base_libdir}/firmware/hdmitxfw.bin \
-    ${nonarch_base_libdir}/firmware/hdmirxfw.bin \
-    ${nonarch_base_libdir}/firmware/dpfw.bin \
-"
-FILES:${PN}-vpu-amphion = "${nonarch_base_libdir}/firmware/amphion/vpu/*"
-FILES:${PN}-vpu-wave = "${nonarch_base_libdir}/firmware/wave633c_codec_fw.bin"
-
-COMPATIBLE_MACHINE = "(imx-generic-bsp)"
diff --git a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/imx-boot-firmware-files_8.26.1.bb b/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/imx-boot-firmware-files_8.26.1.bb
deleted file mode 100644
index 4c0d51c8a..000000000
--- a/meta-digi-arm/dynamic-layers/freescale-layer/recipes-bsp/firmware-imx/imx-boot-firmware-files_8.26.1.bb
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright (C) 2018-2025 NXP
-SUMMARY = "Freescale i.MX Firmware files used for boot"
-
-require firmware-imx-${PV}.inc
-
-inherit deploy nopackages
-
-do_install[noexec] = "1"
-
-DEPLOY_FOR                  = ""
-DEPLOY_FOR:mx8-generic-bsp  = "mx8"
-DEPLOY_FOR:mx8m-generic-bsp = "mx8m"
-DEPLOY_FOR:mx9-generic-bsp  = "mx9"
-
-deploy_for_mx8() {
-    # Cadence HDMI
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${DEPLOYDIR}
-}
-
-deploy_for_mx8m() {
-    # Synopsys DDR
-    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
-        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
-    done
-
-    # Cadence DP and HDMI
-    install -m 0644 ${S}/firmware/hdmi/cadence/signed_dp_imx8m.bin ${DEPLOYDIR}
-    install -m 0644 ${S}/firmware/hdmi/cadence/signed_hdmi_imx8m.bin ${DEPLOYDIR}
-}
-
-
-deploy_for_mx9() {
-    # Synopsys DDR
-    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
-        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
-    done
-}
-
-python () {
-    # Manually add the required functions as dependencies otherwise they won't be included in the
-    # final run script.
-    deploy_for = d.getVar('DEPLOY_FOR', True).split()
-    for soc in deploy_for:
-        d.appendVarFlag('do_deploy', 'vardeps', ' deploy_for_%s' % soc)
-}
-
-do_deploy () {
-    for soc in ${DEPLOY_FOR}; do
-        bbnote "Running deploy for $soc"
-        deploy_for_$soc
-    done
-}
-
-addtask deploy after do_install before do_build
-
-PACKAGE_ARCH = "${MACHINE_SOCARCH}"
-
-COMPATIBLE_MACHINE                  = "(mx8-generic-bsp|mx9-generic-bsp)"
-COMPATIBLE_MACHINE:mx8x-generic-bsp = "(^$)"