imx-sc-firmware: update to version 0.7

This is needed to match U-Boot's SC API changes. Also, for now, use NXP's
A0 version of the firmware without our customizations until we have access to
the new SCFW SDK.

https://jira.digi.com/browse/DEL-6085

Signed-off-by: Gabriel Valcazar <gabriel.valcazar@digi.com>

meta-digi-arm/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.2.bb

@@ -1,44 +0,0 @@
-# Copyright (C) 2016 Freescale Semiconductor
-# Copyright 2017 NXP
-
-DESCRIPTION = "i.MX System Controller Firmware"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
-SECTION = "BSP"
-
-inherit fsl-eula-unpack pkgconfig deploy
-
-SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
-
-SRC_URI[md5sum] = "6ae8d2ffc24d5cadac9a90c2ff49ecf1"
-SRC_URI[sha256sum] = "f206d017cb9bd1eb554fb76934034dc85d66155ce7a9f55e5ad25a9c8135dd56"
-
-S = "${WORKDIR}/${PN}-${PV}"
-
-SC_MACHINE_NAME ?= "mx8qm-scfw-tcm.bin"
-SC_MACHINE_NAME_mx8qm = "mx8qm-scfw-tcm.bin"
-SC_MACHINE_NAME_mx8qxp = "mx8qx-scfw-tcm.bin"
-
-SYSROOT_DIRS += "/boot"
-
-do_install () {
-    install -d ${D}/boot
-    install -m 0644 ${S}/${SC_MACHINE_NAME} ${D}/boot/
-}
-
-BOOT_TOOLS = "imx-boot-tools"
-
-do_deploy () {
-    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
-    install -m 0644 ${S}/${SC_MACHINE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}/
-}
-
-addtask deploy after do_install
-
-INHIBIT_PACKAGE_STRIP = "1"
-INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-
-FILES_${PN} = "/boot"
-
-COMPATIBLE_MACHINE = "(mx8qm|mx8qxp)"

meta-digi-arm/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.2.bbappend

@@ -1,13 +0,0 @@
-# Copyright (C) 2018 Digi International Inc.
-
-SRC_URI_append = " \
-    file://scfw_tcm.bin \
-"
-
-do_unpack[postfuncs] += "overwrite_scfw"
-overwrite_scfw () {
-	# Overwrite original SCFW file from NXP
-	cp -f ${WORKDIR}/scfw_tcm.bin ${S}/mx8qx-scfw-tcm.bin
-}
-
-COMPATIBLE_MACHINE = "(ccimx8x)"

meta-digi-arm/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bb

@@ -0,0 +1,50 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2018 NXP
+
+DESCRIPTION = "i.MX System Controller Firmware"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ab61cab9599935bfe9f700405ef00f28"
+SECTION = "BSP"
+
+inherit fsl-eula-unpack pkgconfig deploy
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+
+SRC_URI[md5sum] = "9dcdbdae491bd6b027ccab0e354870cb"
+SRC_URI[sha256sum] = "46e487605c31f44b4fe0280e57e4e0a3fe51c375300766805ae1161c39021766"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+BOARD_TYPE ?= "mek"
+SC_FIRMWARE_NAME ?= "mx8qm-mek-scfw-tcm.bin"
+SC_FIRMWARE_NAME_mx8qm = "mx8qm-${BOARD_TYPE}-scfw-tcm.bin"
+SC_FIRMWARE_NAME_mx8qxp = "mx8qx-${BOARD_TYPE}-scfw-tcm.bin"
+symlink_name = "scfw_tcm.bin"
+
+SYSROOT_DIRS += "/boot"
+
+do_install () {
+    install -d ${D}/boot
+    install -m 0644 ${S}/${SC_FIRMWARE_NAME} ${D}/boot/
+}
+
+BOOT_TOOLS = "imx-boot-tools"
+
+do_deploy () {
+    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+    install -m 0644 ${S}/${SC_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}/
+    cd ${DEPLOYDIR}/${BOOT_TOOLS}/
+    rm -f ${symlink_name}
+    ln -sf ${SC_FIRMWARE_NAME} ${symlink_name}
+    cd -
+}
+
+addtask deploy after do_install
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+FILES_${PN} = "/boot"
+
+COMPATIBLE_MACHINE = "(mx8qm|mx8qxp)"

meta-digi-arm/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bbappend

@@ -0,0 +1,5 @@
+# Copyright (C) 2018 Digi International Inc.
+
+SC_FIRMWARE_NAME_ccimx8x = "mx8qx-a0-mek-scfw-tcm.bin"
+
+COMPATIBLE_MACHINE = "(ccimx8x)"