# We have a conf and classes directory, add to BBPATH
BBPATH .= ":${LAYERDIR}"

# We have a packages directory, add to BBFILES
BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
            ${LAYERDIR}/recipes-*/*/*.bbappend"

# Let us add layer-specific bbappends which are only applied when that
# layer is included in our configuration
BBFILES += "${@' '.join('${LAYERDIR}/other-layers/%s/recipes*/*/*.bbappend' % layer \
               for layer in BBFILE_COLLECTIONS.split())}"

BBFILE_COLLECTIONS += "dey"
BBFILE_PATTERN_dey := "^${LAYERDIR}/"
BBFILE_PRIORITY_dey = "6"

LAYERDEPENDS_dey  = "core digi-arm"
LAYERDEPENDS_dey += "openembedded-layer networking-layer webserver qt5-layer"

# Digi's General and Open Source license agreements
DIGI_EULA_FILE = "${LAYERDIR}/DIGI_EULA"
DIGI_OPEN_EULA_FILE = "${LAYERDIR}/DIGI_OPEN_EULA"

# Digi mirror for packages vanished upstream
DIGI_MIRROR ?= "ftp://ftp1.digi.com/support/digiembeddedyocto/mirror/"
MIRRORS += "\
ftp://.*/.*      ${DIGI_MIRROR} \n \
http://.*/.*     ${DIGI_MIRROR} \n \
https://.*/.*    ${DIGI_MIRROR} \n \
"