#@TYPE: Machine
#@NAME: ConnectCore 93 Development Kit
#@DESCRIPTION: Machine configuration for Digi's ConnectCore 93 DVK

DIGI_SOM = "ccimx93"
MACHINEOVERRIDES =. "mx93:${DIGI_FAMILY}:${DIGI_SOM}:"

# Include the machine configuration for Digi's ConnectCore 9 module
include conf/machine/include/ccimx9.inc

# Console
SERIAL_CONSOLES = "115200;ttyLP5"

# Bluetooth tty
BT_TTY ?= "ttyLP0"

# Firmware
MACHINE_FIRMWARE:append = " ${@oe.utils.conditional('HAVE_WIFI', '1', 'firmware-nxp-wifi-nxpiw612-sdio firmware-murata-nxp', '', d)}"
MACHINE_FIRMWARE:append = " ethos-u-firmware"

# Wi-Fi
WIRELESS_MODULE ?= ""
WIRELESS_MODULE:append = " ${@oe.utils.conditional('HAVE_WIFI', '1', 'kernel-module-nxp-wlan', '', d)}"
HAS_WIFI_VIRTWLANS = "true"
WLAN_P2P_INTERFACE = "p2p0"
MACHINE_EXTRA_RRECOMMENDS += "${WIRELESS_MODULE}"

# XBee
XBEE_RESET_N_GPIO ?= "gpio2@19"
XBEE_SLEEP_RQ_GPIO ?= ""
XBEE_TTY ?= "ttyLP3"

# U-Boot configurations
UBOOT_CONFIG ??= "ccimx93-dvk"
UBOOT_CONFIG[ccimx93-dvk] = "ccimx93-dvk_defconfig"

# Index of USB device for installer
UBOOT_INSTALL_USB_INDEX = "0"
# Index of microSD device for installer
UBOOT_INSTALL_SD_INDEX = "1"

# imx-boot configurations
ATF_PLATFORM = "imx93"
IMX_BOOT_SOC_TARGET = "iMX93"
IMXBOOT_TARGETS = "flash_singleboot flash_singleboot_a0"
# Generate images for all SOC revisions (keep the override as otherwise the
# one in "use-imx-security-controller-firmware.bbclass" takes precedence)
SECO_FIRMWARE_NAME:ccimx93 = "mx93??-ahab-container.img"

DDR_FIRMWARE_NAME = " \
    lpddr4_dmem_1d_v202201.bin \
    lpddr4_dmem_2d_v202201.bin \
    lpddr4_imem_1d_v202201.bin \
    lpddr4_imem_2d_v202201.bin \
"

KERNEL_DEVICETREE ?= " \
    digi/ccimx9_bt-dtm.dtbo \
    digi/ccimx9_bt.dtbo \
    digi/ccimx93_emulate-ccimx91.dtbo \
    digi/ccimx93_npu.dtbo \
    digi/ccimx93_single-core-512M.dtbo \
    digi/ccimx9_wifi.dtbo \
    digi/ccimx9-dvk_enet2.dtbo \
    digi/ccimx9-dvk_mikroe-accel2-click.dtbo \
    digi/ccimx9-dvk_mikroe-gyro-click.dtbo \
    digi/ccimx93-dvk_dlc0200ccp04df-mipi-dsi.dtbo \
    digi/ccimx93-dvk_lvds-g101evn010.dtbo \
    digi/ccimx93-dvk_nhd-3-5-640480ef-msxp-mipi-dsi.dtbo \
    digi/ccimx93-dvk.dtb \
    ${@bb.utils.contains('DISTRO_FEATURES', 'tsn', 'digi/ccimx9-dvk_eqos-tsn.dtbo', '', d)} \
"
FIT_CONF_DEFAULT_DTB = "ccimx93-dvk.dtb"

# Per-machine DISTRO_FEATURES customization
MACHINE_DISTRO_FEATURES_REMOVE = "vulkan"

# Boot artifacts to be copied from the deploy dir to the installer ZIP
BOOTABLE_ARTIFACTS = " \
    imx-boot##SIGNED##-ccimx93-dvk.bin \
    imx-boot##SIGNED##-ccimx93-dvk-A0.bin \
"